如何查看邮箱的建立时间？

一阵风儿

本公司现用Exchange２００３系统，现Boss要求，将所有邮箱的建立时间统计出来，进行制表，这可难倒了小弟，请各位达人不吝赐教！谢谢！

karson

我也想知道

一阵风儿

怎么没有人知道吗？

tarian

俺知道了，呵呵。看图：




应该还有工具可以查看的，你找关键字：查看AD用户创建时间

当然还能在安全日志中看到（需要启用账户审核策略）。只是要慢慢找。

[ 本帖最后由 tarian 于 2009-8-13 23:12 编辑 ]

钉子

然后....怎么导出一张表呢?

一阵风儿

上述只是user建立的时间，并不是邮箱建立的时间啊？哎！

钉子

看来Tarian要继续...

想Fei的猪

使用脚本,获取MAPI属性,根据网上的脚本修改后如下:
servername = "172.18.2.243"
PR_NTSDModificationTime = &H3FD60040
Set fso = CreateObject("Scripting.FileSystemObject")
set wfile = fso.opentextfile("c:\mbCreationTime.csv",2,true)
wfile.writeline("Mailbox,CreationTime")
        Const ADS_SCOPE_SUBTREE = 3
        Set objConnection = CreateObject("ADODB.Connection")
        Set objCommand =   CreateObject("ADODB.Command")
        objConnection.Provider = "ADsDSOObject"
        objConnection.Open "Active Directory Provider"     
        Set objCOmmand.ActiveConnection = objConnection
        objCommand.CommandText = _
            "Select name,mail from 'LDAP://OU=The9,DC=PD,DC=the9,DC=com'Where objectClass='user'"  
        objCommand.Properties("Page Size") = 1000
        objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
        Set objRecordSet = objCommand.Execute
        objRecordSet.MoveFirst  
        Do Until objRecordSet.EOF
            UserName = objRecordSet.Fields("Name").Value  
            UserMail = objRecordSet.Fields("Mail").Value   
            If isNull(UserMail) = True Then
            Else
            Call procmailboxes(servername,UserMail)
            End If
            objRecordSet.MoveNext
        Loop

Wscript.Echo "Done.."

sub procmailboxes(servername,MailboxAlias)
Set msMapiSession = CreateObject("MAPI.Session")
on error Resume next
msMapiSession.Logon "","",False,True,True,True,Servername & vbLF & MailboxAlias
if err.number = 0 then
on error goto 0
Set objInbox = msMapiSession.Inbox
Set objInfostore = msMapiSession.GetInfoStore(objInbox.StoreID)
Set objRootFolder = objInfostore.Rootfolder
Set Non_IPM_rootFolder = msMapiSession.GetFolder(objRootfolder.fields.item(&h0E090102),objInfoStore.ID)
wfile.writeline(UserName & "," & Non_IPM_rootFolder.fields.item(PR_NTSDModificationTime))
else
wfile.writeline(UserName & "," & "Error Opening Mailbox")
end if
Set msMapiSession = Nothing
Set mrMailboxRules = Nothing
End Sub

注意以下步骤：
1. 不要用Administrator测试，因为MailBox的Full Control对Administrator是Deny的.
所以，新建一个普通user，然后在Exchange“系统管理器”里，添加对Exchange Server的Full Control权限.
2. 更改脚本：
  a. 修改第一行的ServerName，这里用Exchange Server的IP地址或者NetBios Name。
  b. 修改LDAP位置，“LDAP://OU=The9,DC=PD,DC=the9,DC=com”修改为自己的LDAP信息。
3. 双击脚本运行。
请测试了看看,如果有问题,请提出..

想Fei的猪

如果测试成功,会在C盘根目录产生一个csv的文件.

一阵风儿

谢谢！己经成功！